Upload magma

2024-03-04 21:16:02 +13:00 · 2024-03-04 21:16:02 +13:00 · dfa9ee0b24
commit dfa9ee0b24
5008 changed files with 653442 additions and 0 deletions
--- a/buildSrc/.gradle/8.1.1/executionHistory/executionHistory.bin
+++ b/buildSrc/.gradle/8.1.1/executionHistory/executionHistory.bin
--- a/buildSrc/.gradle/8.1.1/executionHistory/executionHistory.lock
+++ b/buildSrc/.gradle/8.1.1/executionHistory/executionHistory.lock
--- a/buildSrc/.gradle/buildOutputCleanup/buildOutputCleanup.lock
+++ b/buildSrc/.gradle/buildOutputCleanup/buildOutputCleanup.lock
--- a/buildSrc/.gradle/buildOutputCleanup/cache.properties
+++ b/buildSrc/.gradle/buildOutputCleanup/cache.properties
@ -0,0 +1,2 @@
+#Mon Mar 04 20:53:28 NZDT 2024
+gradle.version=8.1.1
--- a/buildSrc/.gradle/buildOutputCleanup/outputFiles.bin
+++ b/buildSrc/.gradle/buildOutputCleanup/outputFiles.bin
--- a/buildSrc/.gradle/file-system.probe
+++ b/buildSrc/.gradle/file-system.probe
--- a/buildSrc/.gradle/noVersion/buildSrc.lock
+++ b/buildSrc/.gradle/noVersion/buildSrc.lock
--- a/buildSrc/build.gradle
+++ b/buildSrc/build.gradle
@ -0,0 +1,13 @@
+repositories {
+    maven { url = 'https://maven.minecraftforge.net/' }
+	 mavenCentral()
+}
+
+dependencies {
+    implementation 'org.ow2.asm:asm:9.5'
+    implementation 'org.ow2.asm:asm-tree:9.5'
+    implementation 'net.minecraftforge:srgutils:0.5.+'
+    implementation 'commons-io:commons-io:2.12.0'
+    implementation 'com.google.code.gson:gson:2.10.1'
+    implementation 'org.eclipse.jgit:org.eclipse.jgit:6.5.0.202303070854-r'
+}
--- a/buildSrc/build/libs/buildSrc.jar
+++ b/buildSrc/build/libs/buildSrc.jar
--- a/buildSrc/build/tmp/jar/MANIFEST.MF
+++ b/buildSrc/build/tmp/jar/MANIFEST.MF
@ -0,0 +1,2 @@
+Manifest-Version: 1.0
+
--- a/buildSrc/index.html
+++ b/buildSrc/index.html
@ -0,0 +1,9 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/</h1><hr><pre><a href="../">../</a>
+<a href="src/">src/</a>                                               07-Oct-2023 14:12       -
+<a href="build.gradle">build.gradle</a>                                       07-Oct-2023 14:12     441
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="9d25feee8cddfab156a6f2370ef49241" data-cf-beacon='{"rayId":"85f014da2b2250c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/index.html
+++ b/buildSrc/src/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/</h1><hr><pre><a href="../">../</a>
+<a href="main/">main/</a>                                              07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="9cb95c8f2ef1d2e1c9c952c935ce53e5" data-cf-beacon='{"rayId":"85f0151bca9850c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/index.html
+++ b/buildSrc/src/main/groovy/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/</h1><hr><pre><a href="../">../</a>
+<a href="net/">net/</a>                                               07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="b463c6d4dea14dfabad889371869055b" data-cf-beacon='{"rayId":"85f01595cf3a50c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/net/index.html
+++ b/buildSrc/src/main/groovy/net/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/</h1><hr><pre><a href="../">../</a>
+<a href="minecraftforge/">minecraftforge/</a>                                    07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="71438cb53c8c343faafbc246b633e645" data-cf-beacon='{"rayId":"85f015f60f6f50c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/index.html
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/</h1><hr><pre><a href="../">../</a>
+<a href="tasks/">tasks/</a>                                             07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="2ac76b6911addc5a1cce17489d9a14e7" data-cf-beacon='{"rayId":"85f01976d8d150c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/BytecodeFinder.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/BytecodeFinder.groovy
@ -0,0 +1,50 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.json.JsonBuilder
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.Internal
+import org.gradle.api.tasks.TaskAction
+import org.objectweb.asm.tree.ClassNode
+import org.objectweb.asm.tree.FieldNode
+import org.objectweb.asm.tree.MethodNode
+
+abstract class BytecodeFinder extends DefaultTask {
+    @InputFile abstract RegularFileProperty getJar()
+    // It should be fine to mark the output as internal as we want to control when we run it anyways.
+    // This also shuts Gradle 8 up about implicit task dependencies.
+    @Internal abstract RegularFileProperty getOutput()
+
+    BytecodeFinder() {
+        output.convention(project.layout.buildDirectory.dir(name).map { it.file("output.json") })
+    }
+
+    @TaskAction
+    protected void exec() {
+        Util.init()
+
+        def outputFile = output.get().asFile
+        if (outputFile.exists())
+            outputFile.delete()
+
+        pre()
+
+        Util.processClassNodes(jar.get().asFile, this::process)
+
+        post()
+        outputFile.text = new JsonBuilder(getData()).toPrettyString()
+    }
+
+
+    protected process(ClassNode node) {
+        if (node.fields != null) node.fields.each { process(node, it) }
+        if (node.methods != null) node.methods.each { process(node, it) }
+    }
+
+    protected pre() {}
+    protected process(ClassNode parent, FieldNode node) {}
+    protected process(ClassNode parent, MethodNode node) {}
+    protected post() {}
+    protected abstract Object getData()
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/BytecodePredicateFinder.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/BytecodePredicateFinder.groovy
@ -0,0 +1,32 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.transform.CompileStatic
+import org.gradle.api.provider.Property
+import org.gradle.api.tasks.Internal
+import org.objectweb.asm.tree.ClassNode
+import org.objectweb.asm.tree.MethodNode
+
+@CompileStatic
+abstract class BytecodePredicateFinder extends BytecodeFinder {
+
+    @Internal
+    abstract Property<Closure<Boolean>> getPredicate()
+
+    private final Set<String> matches = new HashSet()
+
+    @Override
+    protected process(ClassNode parent, MethodNode node) {
+        for (final current : node.instructions) {
+            if (predicate.get().call(parent, node, current)) {
+                matches.add(parent.name)
+                return
+            }
+        }
+    }
+
+    @Internal
+    @Override
+    protected Object getData() {
+        return matches.toSorted(Comparator.naturalOrder()) ?: {throw new RuntimeException('Failed to find any targets, please ensure that method names and descriptors are correct.')}()
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ClosureHelper.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ClosureHelper.groovy
@ -0,0 +1,31 @@
+package net.minecraftforge.forge.tasks
+
+import java.util.function.BiConsumer
+
+public class ClosureHelper {
+    BiConsumer<String, Closure> callback
+    
+    public ClosureHelper(Closure cl, BiConsumer<String, Closure> callback) {
+        this.callback = callback
+        apply(this, cl)
+    }
+    
+    
+    def methodMissing(String name, Object args) {
+        if (!args.class.isArray()) return
+        Object[] aargs = (Object[])args
+        
+        if (aargs.length == 1 && aargs[0] instanceof Closure) {
+            this.callback.accept(name, (Closure)aargs[0])
+        } else {
+            throw new IllegalArgumentException('Unknown method: "' + name + '" with arguments ' + args + ' for ' + this)
+        }
+    }
+    
+    static <T> T apply(T obj, Closure cl) {
+        cl.delegate = obj
+        cl.resolveStrategy = Closure.DELEGATE_FIRST
+        cl()
+        return obj
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/Crowdin.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/Crowdin.groovy
@ -0,0 +1,73 @@
+package net.minecraftforge.forge.tasks
+
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.provider.Property
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.Optional
+import org.gradle.api.tasks.OutputFile
+import org.gradle.api.tasks.TaskAction
+
+import java.util.zip.ZipEntry
+import java.util.zip.ZipInputStream
+import java.util.zip.ZipOutputStream
+
+abstract class Crowdin extends DefaultTask {
+    @Input abstract Property<String> getId()
+	@Input @Optional abstract Property<String> getKey()
+	@Input boolean json = true
+	@OutputFile abstract RegularFileProperty getOutput()
+	@OutputFile abstract RegularFileProperty getExport()
+
+    Crowdin() {
+		outputs.upToDateWhen{ false }
+		id.convention('minecraft-forge')
+		output.convention(project.layout.buildDirectory.dir(name).map {it.file("output.zip") })
+		export.convention(project.layout.buildDirectory.dir(name).map {it.file("export.json") })
+	}
+
+    @TaskAction
+    def run() {
+		File outputFile = output.get().asFile
+		File exportFile = export.get().asFile
+		if (outputFile.exists())
+			outputFile.delete()
+		
+		if (!key.isPresent())
+			return
+		String key = this.key.get()
+		String id = this.id.get()
+		
+		// Force an export
+		new URL("https://api.crowdin.com/api/project/${id}/export?key=${key}").withInputStream { i ->
+			exportFile.withOutputStream { it << i }
+		}
+		
+		if (!exportFile.text.contains('success')) {
+			throw new RuntimeException("Crowdin export failed, see ${exportFile} for more info")
+		}
+
+		new URL("https://api.crowdin.com/api/project/${id}/download/all.zip?key=${key}").withInputStream { i -> 
+			new ZipInputStream(i).withCloseable { zin ->
+				outputFile.withOutputStream { out ->
+					new ZipOutputStream(out).withCloseable { zout -> 
+						ZipEntry zein
+						while ((zein = zin.nextEntry) != null) {
+							if (zein.isDirectory()) {
+								zout.putNextEntry(new ZipEntry(zein.name))
+							} else {
+								// 1.13+ uses json
+								if (zein.name.endsWith('.json') == json) {
+									ZipEntry zeout = new ZipEntry(json ? zein.name.toLowerCase() : zein.name)
+									zeout.time = 1
+									zout.putNextEntry(zeout)
+									zout << zin
+								}
+							}
+						}
+					}
+				}
+			}
+		}
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/DownloadLibraries.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/DownloadLibraries.groovy
@ -0,0 +1,54 @@
+package net.minecraftforge.forge.tasks
+
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.DirectoryProperty
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.Internal
+import org.gradle.api.tasks.OutputFile
+import org.gradle.api.tasks.OutputFiles
+import org.gradle.api.tasks.TaskAction
+import org.gradle.api.tasks.OutputDirectory
+
+import java.nio.file.Files
+
+abstract class DownloadLibraries extends DefaultTask {
+	@InputFile abstract RegularFileProperty getInput()
+	@OutputDirectory abstract DirectoryProperty getOutput()
+	@OutputFile abstract RegularFileProperty getLibrariesOutput()
+
+    DownloadLibraries() {
+		output.convention(project.layout.buildDirectory.dir(name))
+        librariesOutput.convention(project.layout.buildDirectory.dir(name).map(d -> d.file('libraries.txt')))
+	}
+
+    @TaskAction
+    def run() {
+		Util.init()
+		File outputDir = output.get().asFile
+        def libraries = new ArrayList()
+
+		def json = input.get().asFile.json().libraries.each { lib ->
+		    //TODO: Thread?
+			def artifacts = [lib.downloads.artifact] + lib.downloads.get('classifiers', [:]).values()
+			artifacts.each{ art -> 
+				def target = new File(outputDir, art.path)
+				libraries.add(target.absolutePath)
+				if (!target.exists() || !art.sha1.equals(target.sha1())) {
+					project.logger.lifecycle("Downloading ${art.url}")
+					if (!target.parentFile.exists()) {
+						target.parentFile.mkdirs()
+					}
+					new URL(art.url).withInputStream { i ->
+						target.withOutputStream { it << i }
+					}
+					if (!art.sha1.equals(target.sha1())) {
+						throw new IllegalStateException("Failed to download ${art.url} to ${target.canonicalPath} SHA Mismatch")
+					}
+				}
+			}
+		}
+        Files.write(librariesOutput.get().asFile.toPath(), libraries)
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/FieldCompareFinder.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/FieldCompareFinder.groovy
@ -0,0 +1,109 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.transform.EqualsAndHashCode
+
+import java.util.ArrayList
+import java.util.HashMap
+import java.util.TreeMap
+import java.util.TreeSet
+import java.util.function.BiConsumer
+
+import org.gradle.api.DefaultTask
+import org.gradle.api.tasks.*
+
+import org.objectweb.asm.Opcodes
+import org.objectweb.asm.Type
+import org.objectweb.asm.tree.ClassNode
+import org.objectweb.asm.tree.FieldNode
+import org.objectweb.asm.tree.MethodNode
+
+import static org.objectweb.asm.Opcodes.*
+
+abstract class FieldCompareFinder extends BytecodeFinder {
+    @Nested
+    Map<String, Search> fields = [:] as HashMap
+    @Internal
+    Map<Search, String> fieldsReverse = [:] as HashMap
+    @Internal
+    Map<String, Set<ObjectTarget>> targets = [:] as TreeMap
+    
+    @Override
+    protected pre() {
+        //fields.each{ k,v -> logger.lifecycle("Fields: " + k + ' ' + v) }
+    }
+    
+    @Override
+    protected process(ClassNode parent, MethodNode node) {
+        def last = null
+        def parentInstance = new ObjectTarget(owner: parent.name, name: '', desc: '')
+        for (int x = 0; x < node.instructions.size(); x++) {
+            def current = node.instructions.get(x)
+            if (current.opcode == IF_ACMPEQ || current.opcode == IF_ACMPNE) {
+                if (last != null && (last.opcode == GETSTATIC || last.opcode == GETFIELD)) {
+                    def target = new Search(cls: last.owner, name: last.name)
+                    def wanted = fieldsReverse.get(target)
+                    def original = fields.get(wanted)
+                    def instance = new ObjectTarget(owner: parent.name, name: node.name, desc: node.desc)
+                    if (wanted != null && (original.blacklist == null || (!original.blacklist.contains(instance) && !original.blacklist.contains(parentInstance)))) {
+                        targets.computeIfAbsent(wanted, { k -> new TreeSet() }).add(instance)
+                    }
+                }
+            }
+            last = current
+        }
+    }
+    
+    @Internal
+    @Override
+    protected Object getData() {
+		def ret = [:] as HashMap
+		targets.forEach{ k, v -> 
+			def e = fields.get(k)
+			ret[k] = [
+				cls: e.cls, 
+				name: e.name, 
+				replacement: e.replacement, 
+				targets: v
+			]
+		}
+        return ret
+    }
+    
+    @EqualsAndHashCode(excludes = ['replacement', 'blacklist'])
+    public static class Search {
+        @Input
+        String cls
+        
+        @Input
+        String name
+		
+		@Input
+		String replacement
+    
+        @Nested
+        @Optional
+        Set<ObjectTarget> blacklist
+        
+        @Override
+        String toString() {
+            return cls + '.' + name
+        }
+        
+        def blacklist(def owner, def name, def desc) {
+            if (blacklist == null)
+                blacklist = new HashSet()
+            blacklist.add(new ObjectTarget(owner: owner, name: name, desc: desc))
+        }
+        def blacklist(def owner) {
+            blacklist(owner, '', '')
+        }
+    }
+    
+    def fields(Closure cl) {
+        new ClosureHelper(cl, {name, ccl ->
+            def search = ClosureHelper.apply(new Search(), ccl)
+            this.fields.put(name, search)
+            this.fieldsReverse.put(search, name)
+        })
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/FixPatchImports.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/FixPatchImports.groovy
@ -0,0 +1,40 @@
+package net.minecraftforge.forge.tasks
+
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.DirectoryProperty
+import org.gradle.api.tasks.InputDirectory
+import org.gradle.api.tasks.TaskAction
+
+import java.nio.file.Files
+
+abstract class FixPatchImports extends DefaultTask {
+
+    @InputDirectory abstract DirectoryProperty getClean()
+    @InputDirectory abstract DirectoryProperty getPatched()
+
+    @TaskAction
+    void run() {
+        final patchedPath = getPatched().get().asFile.toPath()
+        final cleanPath = getClean().get().asFile.toPath()
+
+        try (final var stream = Files.find(patchedPath, Integer.MAX_VALUE, (path, attr) -> path.toString().endsWith('.java'))) {
+            final itr = stream.iterator()
+            while (itr.hasNext()) {
+                final next = itr.next()
+                final clean = cleanPath.resolve(patchedPath.relativize(next).toString())
+
+                final patchedLines = Files.readAllLines(next)
+                final cleanLines = Files.readAllLines(clean)
+
+                final patchedImport = patchedLines.findLastIndexOf(2) { it.startsWith('import ') }
+                final cleanImport = cleanLines.findLastIndexOf(2) { it.startsWith('import ') }
+
+                if (cleanImport !== patchedImport) {
+                    patchedLines.removeIf {  it.startsWith('import ') }
+                    patchedLines.addAll(2, cleanLines.subList(2, cleanImport + 1))
+                    Files.write(next, patchedLines)
+                }
+            }
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InheritanceData.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InheritanceData.groovy
@ -0,0 +1,49 @@
+package net.minecraftforge.forge.tasks
+
+import com.google.gson.Gson
+import com.google.gson.reflect.TypeToken
+import groovy.transform.CompileStatic
+import groovy.transform.TupleConstructor
+
+@CompileStatic
+@TupleConstructor
+final class InheritanceData implements Annotatable {
+    String name
+    int access
+    String superName
+    List<String> interfaces = []
+    Map<String, Method> methods = [:]
+    Map<String, Field> fields = [:]
+    List<Annotation> annotations = []
+
+    @TupleConstructor
+    static final class Method implements Annotatable {
+        int access
+        String override
+        List<Annotation> annotations = []
+    }
+
+    @TupleConstructor
+    static final class Field implements Annotatable {
+        int access
+        String desc
+        List<Annotation> annotations = []
+    }
+
+    @TupleConstructor
+    static final class Annotation {
+        String desc
+    }
+
+    private static final Gson GSON = new Gson()
+    static Map<String, InheritanceData> parse(File file) {
+        try (final reader = file.newReader()) {
+            return GSON.fromJson(reader, new TypeToken<Map<String, InheritanceData>>() {})
+        }
+    }
+}
+
+@CompileStatic
+interface Annotatable {
+    List<InheritanceData.Annotation> getAnnotations()
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InstallerJar.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InstallerJar.groovy
@ -0,0 +1,44 @@
+package net.minecraftforge.forge.tasks
+
+import org.gradle.api.tasks.bundling.Zip
+import org.gradle.api.tasks.*
+import org.gradle.api.provider.SetProperty
+
+abstract class InstallerJar extends Zip {
+    @Input @Optional abstract SetProperty<String> getPackedDependencies()
+
+    InstallerJar() {
+        archiveClassifier.set('installer')
+        archiveExtension.set('jar') // Needs to be Zip task to not override Manifest, so set extension
+        destinationDirectory.set(project.layout.buildDirectory.dir('libs'))
+
+        def installerJson = project.tasks.installerJson
+        def launcherJson = project.tasks.launcherJson
+        def downloadInstaller = project.tasks.downloadInstaller
+
+        dependsOn(installerJson, launcherJson, downloadInstaller)
+        from(installerJson, launcherJson)
+
+        from(project.rootProject.file('/src/main/resources/url.png'))
+        project.afterEvaluate {
+            from(project.zipTree(downloadInstaller.output)) {
+                duplicatesStrategy = 'exclude'
+            }
+
+            if (!System.env.TEAMCITY_VERSION) {
+                dependsOn(project.universalJar)
+                from(project.universalJar) {
+                    into '/maven/' + project.group.replace('.', '/') + '/' + project.universalJar.archiveBaseName.get() + '/' + project.version + '/'
+                }
+
+                packedDependencies.get().forEach {
+                    def jarTask = project.rootProject.getTasks().findByPath(it)
+                    dependsOn(jarTask)
+                    from(jarTask) {
+                        into '/maven/' + jarTask.project.group.replace('.', '/') + '/' + jarTask.archiveBaseName.get() + '/' + jarTask.project.version + '/'
+                    }
+                }
+            }
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InstallerJson.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/InstallerJson.groovy
@ -0,0 +1,81 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.json.JsonBuilder
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.provider.Property
+import org.gradle.api.provider.SetProperty
+import org.gradle.api.tasks.*
+
+import java.nio.file.Files
+
+abstract class InstallerJson extends DefaultTask {
+    @OutputFile abstract RegularFileProperty getOutput()
+    @InputFiles abstract ConfigurableFileCollection getInput()
+    @Input @Optional abstract SetProperty<String> getPackedDependencies()
+    @Input @Optional final Map<String, Object> libraries = new LinkedHashMap<>()
+    @Input Map<String, Object> json = new LinkedHashMap<>()
+    @InputFile abstract RegularFileProperty getIcon()
+    @Input abstract Property<String> getLauncherJsonName()
+    @Input abstract Property<String> getLogo()
+    @Input abstract Property<String> getMirrors()
+    @Input abstract Property<String> getWelcome()
+
+    InstallerJson() {
+        getLauncherJsonName().convention('/version.json')
+        getLogo().convention('/big_logo.png')
+        getMirrors().convention('https://files.minecraftforge.net/mirrors-2.0.json')
+        getWelcome().convention("Welcome to the simple ${project.name.capitalize()} installer.")
+                
+        getOutput().convention(project.layout.buildDirectory.file('install_profile.json'))
+
+        ['client', 'server'].each { side ->
+            ['slim', 'extra'].each { type ->
+                def tsk = project.tasks.getByName("download${side.capitalize()}${type.capitalize()}")
+                dependsOn(tsk)
+                input.from(tsk.output)
+            }
+            def tsk = project.tasks.getByName("create${side.capitalize()}SRG")
+            dependsOn(tsk)
+            input.from(tsk.output)
+        }
+
+        
+        project.afterEvaluate {
+            (packedDependencies.get().collect{ project.rootProject.tasks.findByPath(it) } + [project.universalJar]).forEach {
+                dependsOn(it)
+                input.from it.archiveFile
+            }
+        }
+    }
+
+    @TaskAction
+    protected void exec() {
+        def libs = libraries
+        for (def child : packedDependencies.get().collect{ project.rootProject.tasks.findByPath(it) } + [project.universalJar]) {
+            def dep = Util.getMavenDep(child)
+            def path = Util.getMavenPath(child)
+            libs.put(dep.toString(), [
+                name: dep,
+                downloads: [
+                    artifact: [
+                        path: path,
+                        url: "https://maven.minecraftforge.net/${path}",
+                        sha1: child.archiveFile.get().asFile.sha1(),
+                        size: child.archiveFile.get().asFile.length()
+                    ]
+                ]
+            ])
+        }
+        json.libraries = libs.values().sort{a,b -> a.name.compareTo(b.name)}
+        json.icon = "data:image/png;base64," + new String(Base64.getEncoder().encode(Files.readAllBytes(icon.get().asFile.toPath())))
+        json.json = launcherJsonName.get()
+        json.logo = logo.get()
+        if (!mirrors.get().isEmpty())
+            json.mirrorList = mirrors.get()
+        json.welcome = welcome.get()
+
+        Files.writeString(output.get().getAsFile().toPath(), new JsonBuilder(json).toPrettyString())
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/LauncherJson.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/LauncherJson.groovy
@ -0,0 +1,74 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.json.JsonBuilder
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.provider.SetProperty
+import org.gradle.api.tasks.*
+
+import java.nio.file.Files
+
+import static net.minecraftforge.forge.tasks.Util.getArtifacts
+import static net.minecraftforge.forge.tasks.Util.iso8601Now
+
+abstract class LauncherJson extends DefaultTask {
+    @OutputFile abstract RegularFileProperty getOutput()
+    @InputFiles abstract ConfigurableFileCollection getInput()
+    @Input Map<String, Object> json = new LinkedHashMap<>()
+    @Input @Optional abstract SetProperty<String> getPackedDependencies()
+    
+    @Internal final vanilla = project.project(':mcp').file('build/mcp/downloadJson/version.json')
+    @Internal final timestamp = iso8601Now()
+    @Internal final comment = [
+        "Please do not automate the download and installation of Forge.",
+        "Our efforts are supported by ads from the download page.",
+        "If you MUST automate this, please consider supporting the project through https://www.patreon.com/LexManos/"
+    ]
+    @Internal final id = "${project.rootProject.ext.MC_VERSION}-${project.name}${project.version.substring(project.rootProject.ext.MC_VERSION.length())}"
+
+    LauncherJson() {
+        getOutput().convention(project.layout.buildDirectory.file('version.json'))
+
+        dependsOn(':fmlloader:jar', 'universalJar')
+        getInput().from(project.tasks.universalJar.archiveFile,
+                project.project(':fmlloader').jar.archiveFile,
+                vanilla)
+                
+        project.afterEvaluate {
+            packedDependencies.get().forEach {
+                def jarTask = project.rootProject.tasks.findByPath(it)
+                dependsOn(jarTask)
+                input.from jarTask.archiveFile
+            }
+        }
+    }
+
+    @TaskAction
+    protected void exec() {
+        if (!json.libraries)
+            json.libraries = []
+        def libs = [:]
+        getArtifacts(project, project.configurations.installer, false).each { key, lib -> libs[key] = lib }
+        getArtifacts(project, project.configurations.moduleonly, false).each { key, lib -> libs[key] = lib }
+
+        packedDependencies.get().collect{ project.rootProject.tasks.findByPath(it) }.forEach {
+            def path = Util.getMavenPath(it)
+            def key = Util.getMavenDep(it)
+            
+            libs[key] = [
+                name: key,
+                downloads: [
+                    artifact: [
+                        path: path,
+                        url: "https://maven.minecraftforge.net/${path}",
+                        sha1: it.archiveFile.get().asFile.sha1(),
+                        size: it.archiveFile.get().asFile.length()
+                    ]
+                ]
+            ]
+        }
+        libs.each { key, lib -> json.libraries.add(lib) }
+        Files.writeString(output.get().asFile.toPath(), new JsonBuilder(json).toPrettyString())
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/MergeJars.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/MergeJars.groovy
@ -0,0 +1,44 @@
+package net.minecraftforge.forge.tasks
+
+import org.apache.commons.io.IOUtils
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFiles
+import org.gradle.api.tasks.OutputFile
+import org.gradle.api.tasks.TaskAction
+
+import java.util.zip.ZipEntry
+import java.util.zip.ZipInputStream
+import java.util.zip.ZipOutputStream
+
+abstract class MergeJars extends DefaultTask {
+    MergeJars() {
+        output.convention(project.layout.buildDirectory.dir(name).map { it.file('output.jar') })
+    }
+
+    @TaskAction
+    void run() {
+        def jars = inputJars.files
+
+        try (ZipOutputStream zout = new ZipOutputStream(new FileOutputStream(output.get().asFile))) {
+            for (def jar : jars) {
+                try (ZipInputStream zin = new ZipInputStream(new FileInputStream(jar))) {
+                    def entry
+                    while ((entry = zin.getNextEntry()) != null) {
+                        ZipEntry _new = new ZipEntry(entry.getName())
+                        _new.setTime(0) //SHOULD be the same time as the main entry, but NOOOO _new.setTime(entry.getTime()) throws DateTimeException, so you get 0, screw you!
+                        zout.putNextEntry(_new)
+                        IOUtils.copy(zin, zout)
+                    }
+                }
+            }
+        }
+    }
+
+    @InputFiles
+    abstract ConfigurableFileCollection getInputJars()
+
+    @OutputFile
+    abstract RegularFileProperty getOutput()
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ObjectTarget.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ObjectTarget.groovy
@ -0,0 +1,32 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.transform.EqualsAndHashCode
+
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.Nested
+import org.gradle.api.tasks.Optional
+
+@EqualsAndHashCode
+public class ObjectTarget implements Comparable<ObjectTarget> {
+    @Input
+    String owner
+    
+    @Input
+    String name
+    
+    @Input
+    @Optional
+    String desc
+    
+    @Override
+    String toString() {
+        if (desc == null)
+            return owner + '.' + name
+        return owner + '.' + name + desc
+    }
+    
+    @Override
+    int compareTo(ObjectTarget o) {
+        return toString().compareTo(o.toString())
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/SetupCheckJarCompatibility.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/SetupCheckJarCompatibility.groovy
@ -0,0 +1,57 @@
+package net.minecraftforge.forge.tasks
+
+import org.gradle.api.DefaultTask
+import org.gradle.api.artifacts.Dependency
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.provider.Property
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.Optional
+import org.gradle.api.tasks.OutputFile
+import org.gradle.api.tasks.TaskAction
+
+import java.nio.file.Files
+import java.nio.file.StandardCopyOption
+
+abstract class SetupCheckJarCompatibility extends DefaultTask {
+    SetupCheckJarCompatibility() {
+        group = 'jar compatibility'
+        onlyIf {
+            inputVersion.getOrNull() != null
+        }
+        outputs.upToDateWhen { false } // Never up to date, because this setup task should always run
+
+        baseBinPatchesOutput.convention(project.layout.buildDirectory.dir(name).map { it.file('joined.lzma') })
+    }
+
+    @TaskAction
+    void run() {
+        def inputVersion = inputVersion.get()
+        def fmlLibs = project.configurations.detachedConfiguration(project.PACKED_DEPS.collect {
+            def artifactId = it.split(':')[1]
+            return project.dependencies.create("net.minecraftforge:${artifactId}:${inputVersion}")
+        }.toArray(Dependency[]::new))
+
+        project.tasks.named('checkJarCompatibility') {
+            baseLibraries.from(project.provider {
+                fmlLibs.resolvedConfiguration.lenientConfiguration.files
+            })
+        }
+
+        def baseForgeUserdev = project.layout.buildDirectory.dir(name).map { it.file("forge-${inputVersion}-userdev.jar") }.get().asFile
+        project.rootProject.extensions.download.run {
+            src "https://maven.minecraftforge.net/net/minecraftforge/forge/${inputVersion}/forge-${inputVersion}-userdev.jar"
+            dest baseForgeUserdev
+        }
+
+        def joinedLzma = project.zipTree(baseForgeUserdev).matching { it.include('joined.lzma') }.singleFile
+
+        Files.copy(joinedLzma.toPath(), baseBinPatchesOutput.get().asFile.toPath(), StandardCopyOption.REPLACE_EXISTING)
+    }
+
+    @Input
+    @Optional
+    abstract Property<String> getInputVersion()
+
+    @OutputFile
+    abstract RegularFileProperty getBaseBinPatchesOutput()
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/TeamcityRequests.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/TeamcityRequests.groovy
@ -0,0 +1,74 @@
+package net.minecraftforge.forge.tasks
+
+import com.google.gson.Gson
+import com.google.gson.reflect.TypeToken
+import groovy.transform.CompileStatic
+import org.eclipse.jgit.api.Git
+
+import javax.annotation.Nullable
+import java.util.stream.Collectors
+
+@CompileStatic
+class TeamcityRequests {
+    public static final Gson GSON = new Gson()
+
+    @Nullable
+    static <T> T jsonRequest(TypeToken<T> clazz, String url) throws Exception {
+        final HttpURLConnection conn = (HttpURLConnection) URI.create(url).toURL().openConnection()
+        conn.setRequestProperty('Accept', 'application/json')
+        conn.setReadTimeout(5 * 1000)
+        conn.setConnectTimeout(5 * 1000)
+        conn.connect()
+
+        if (conn.responseCode !== 200) {
+            return null
+        }
+
+        try (final InputStream is = conn.getInputStream()) {
+            GSON.fromJson(new InputStreamReader(is), clazz.getType())
+        }
+    }
+
+    @Nullable
+    static Map<String, Build> buildsByCommit() throws IOException {
+        final Map<String, Build> builds = [:]
+        jsonRequest(new TypeToken<Builds>() {}, "https://teamcity.minecraftforge.net/guestAuth/app/rest/builds?fields=build:(revisions,number)&locator=buildType:(id:MinecraftForge_MinecraftForge_MinecraftForge_MinecraftForge__Build),count:300,status:SUCCESS")
+                ?.build?.forEach {
+            it.revisions.revision.each { rev -> builds[rev.version] = it }
+        }
+        return builds
+    }
+
+    @Nullable
+    static String attemptFindBase(File gitPath) {
+        try (final git = Git.open(gitPath)) {
+            final Map<String, Build> buildByCommit = buildsByCommit()
+            for (final commit in git.log().setMaxCount(100).call()) {
+                // Find the first commit which was built on CI
+                final build = buildByCommit[commit.id.name]
+                if (build) {
+                    return build.number
+                }
+            }
+        } catch (Exception ignored) {}
+        return null
+    }
+
+    static final class Builds {
+        public List<Build> build
+    }
+
+    static final class Build {
+        public String number
+        public Revisions revisions
+    }
+
+    static final class Revisions {
+        public int count
+        public List<Revision> revision
+    }
+
+    static final class Revision {
+        public String version
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/Util.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/Util.groovy
@ -0,0 +1,165 @@
+package net.minecraftforge.forge.tasks
+
+import groovy.json.JsonBuilder
+import groovy.json.JsonSlurper
+import org.objectweb.asm.ClassReader
+import org.objectweb.asm.Opcodes
+import org.objectweb.asm.tree.ClassNode
+
+import java.io.File
+import java.security.MessageDigest
+import java.text.SimpleDateFormat
+import java.util.Date
+import java.util.zip.ZipEntry
+import java.util.zip.ZipInputStream
+
+public class Util {
+    static final ASM_LEVEL = Opcodes.ASM9
+
+	static void init() {
+		File.metaClass.sha1 = { ->
+			MessageDigest md = MessageDigest.getInstance('SHA-1')
+			delegate.eachByte 4096, {bytes, size ->
+				md.update(bytes, 0, size)
+			}
+			return md.digest().collect {String.format "%02x", it}.join()
+		}
+        File.metaClass.getSha1 = { !delegate.exists() ? null : delegate.sha1() }
+
+		File.metaClass.json = { -> new JsonSlurper().parseText(delegate.text) }
+        File.metaClass.getJson = { return delegate.exists() ? new JsonSlurper().parse(delegate) : [:] }
+        File.metaClass.setJson = { json -> delegate.text = new JsonBuilder(json).toPrettyString() }
+
+		Date.metaClass.iso8601 = { ->
+			def format = new SimpleDateFormat("yyyy-MM-dd'T'HH:mm:ssZ")
+			def result = format.format(delegate)
+			return result[0..21] + ':' + result[22..-1]
+		}
+
+        String.metaClass.rsplit = { String del, int limit = -1 ->
+            def lst = new ArrayList()
+            def x = 0, idx
+            def tmp = delegate
+            while ((idx = tmp.lastIndexOf(del)) != -1 && (limit == -1 || x++ < limit)) {
+                lst.add(0, tmp.substring(idx + del.length(), tmp.length()))
+                tmp = tmp.substring(0, idx)
+            }
+            lst.add(0, tmp)
+            return lst
+        }
+	}
+
+	public static String[] getClasspath(project, libs, artifact) {
+		def ret = []
+		artifactTree(project, artifact).each { key, lib ->
+			libs[lib.name] = lib
+			if (lib.name != artifact)
+				ret.add(lib.name)
+		}
+		return ret
+	}
+
+	public static def getArtifacts(project, config, classifiers) {
+		def ret = [:]
+		config.resolvedConfiguration.resolvedArtifacts.each {
+			def art = [
+				group: it.moduleVersion.id.group,
+				name: it.moduleVersion.id.name,
+				version: it.moduleVersion.id.version,
+				classifier: it.classifier,
+				extension: it.extension,
+				file: it.file
+			]
+			def key = art.group + ':' + art.name
+			def folder = "${art.group.replace('.', '/')}/${art.name}/${art.version}/"
+			def filename = "${art.name}-${art.version}"
+			if (art.classifier != null)
+				filename += "-${art.classifier}"
+			filename += ".${art.extension}"
+			def path = "${folder}${filename}"
+			def url = "https://libraries.minecraft.net/${path}"
+			if (!checkExists(url)) {
+				url = "https://maven.minecraftforge.net/${path}"
+			}
+			ret[key] = [
+				name: "${art.group}:${art.name}:${art.version}" + (art.classifier == null ? '' : ":${art.classifier}") + (art.extension == 'jar' ? '' : "@${art.extension}"),
+				downloads: [
+					artifact: [
+						path: path,
+						url: url,
+						sha1: sha1(art.file),
+						size: art.file.length()
+					]
+				]
+			]
+		}
+		return ret
+	}
+
+    public static def getMavenPath(task) {
+        def classifier = task.archiveClassifier.get()
+        def dep = "${task.project.group}:${task.project.name}:${task.project.version}" + (classifier == '' ? '' : ':' + classifier)
+        return "${task.project.group.replace('.', '/')}/${task.project.name}/${task.project.version}/${task.project.name}-${task.project.version}".toString() + (classifier == '' ? '' : '-' + classifier) + '.jar'
+    }
+
+    public static def getMavenDep(task) {
+        def classifier = task.archiveClassifier.get()
+        return "${task.project.group}:${task.project.name}:${task.project.version}" + (classifier == '' ? '' : ':' + classifier)
+    }
+
+	public static def iso8601Now() { new Date().iso8601() }
+
+	public static def sha1(file) {
+		MessageDigest md = MessageDigest.getInstance('SHA-1')
+		file.eachByte 4096, {bytes, size ->
+			md.update(bytes, 0, size)
+		}
+		return md.digest().collect {String.format "%02x", it}.join()
+	}
+
+	private static def artifactTree(project, artifact) {
+		if (!project.ext.has('tree_resolver'))
+			project.ext.tree_resolver = 1
+		def cfg = project.configurations.create('tree_resolver_' + project.ext.tree_resolver++)
+		def dep = project.dependencies.create(artifact)
+		cfg.dependencies.add(dep)
+		def files = cfg.resolve()
+		return getArtifacts(project, cfg, true)
+	}
+
+	private static boolean checkExists(url) {
+		try {
+			def code = new URL(url).openConnection().with {
+				requestMethod = 'HEAD'
+				connect()
+				responseCode
+			}
+			return code == 200
+		} catch (Exception e) {
+			if (e.toString().contains('unable to find valid certification path to requested target'))
+				throw new RuntimeException('Failed to connect to ' + url + ': Missing certificate root authority, try updating java')
+			throw e
+		}
+	}
+
+    static String getLatestForgeVersion(mcVersion) {
+        final json = new JsonSlurper().parseText(new URL('https://files.minecraftforge.net/net/minecraftforge/forge/promotions_slim.json').getText('UTF-8'))
+        final ver = json.promos["$mcVersion-latest"]
+        ver === null ? null : (mcVersion + '-' + ver)
+    }
+
+    static void processClassNodes(File file, Closure process) {
+        file.withInputStream { i ->
+            new ZipInputStream(i).withCloseable { zin ->
+                ZipEntry zein
+                while ((zein = zin.nextEntry) != null) {
+                    if (zein.name.endsWith('.class')) {
+                        def node = new ClassNode(ASM_LEVEL)
+                        new ClassReader(zin).accept(node, 0)
+                        process(node)
+                    }
+                }
+            }
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ValidateDeprecations.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/ValidateDeprecations.groovy
@ -0,0 +1,92 @@
+/*
+ * Copyright (c) Forge Development LLC and contributors
+ * SPDX-License-Identifier: LGPL-2.1-only
+ */
+
+package net.minecraftforge.forge.tasks
+
+import net.minecraftforge.srgutils.MinecraftVersion
+import org.gradle.api.DefaultTask
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.provider.Property
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.TaskAction
+import org.objectweb.asm.tree.AnnotationNode
+import org.objectweb.asm.tree.ClassNode
+
+abstract class ValidateDeprecations extends DefaultTask {
+    @InputFile
+    abstract RegularFileProperty getInput()
+
+    @Input
+    abstract Property<String> getMcVersion()
+
+    ValidateDeprecations() {
+        this.onlyIf { !System.env.TEAMCITY_VERSION }
+    }
+
+    @TaskAction
+    protected void exec() {
+        def mcVer = MinecraftVersion.from(mcVersion.get())
+        def errors = []
+
+        Util.processClassNodes(input.get().asFile) {
+            processNode(mcVer, errors, it)
+        }
+
+        if (!errors.isEmpty()) {
+            errors.forEach {
+                this.logger.error("Deprecated ${it[0]} is marked for removal in ${it[1]} but is not yet removed")
+            }
+            throw new IllegalStateException("Found deprecated members marked for removal but not yet removed in ${mcVer}; see log for details")
+        }
+    }
+
+    protected processNode(MinecraftVersion mcVer, List<String> errors, ClassNode node) {
+        node.visibleAnnotations?.each { annotation ->
+            ValidateDeprecations.processAnnotations(annotation, mcVer, errors) {
+                "class ${node.name}"
+            }
+        }
+        node.fields?.each { field ->
+            field.visibleAnnotations?.each { annotation ->
+                ValidateDeprecations.processAnnotations(annotation, mcVer, errors) {
+                    "field ${node.name}#${field.name}"
+                }
+            }
+        }
+        node.methods?.each { method ->
+            method.visibleAnnotations?.each { annotation ->
+                ValidateDeprecations.processAnnotations(annotation, mcVer, errors) {
+                    "method ${node.name}#${method.name}${method.desc}"
+                }
+            }
+        }
+    }
+
+    private static void processAnnotations(AnnotationNode annotation, MinecraftVersion mcVer, List<String> errors, Closure context) {
+        def values = annotation.values
+        if (values === null)
+            return
+        int forRemoval = values.indexOf('forRemoval')
+        int since = values.indexOf('since')
+        if (annotation.desc == 'Ljava/lang/Deprecated;' && forRemoval !== -1 && since !== -1 && values.size() >= 4 && values[forRemoval + 1] === true) {
+            def oldVersion = MinecraftVersion.from(values[since + 1])
+            def split = ValidateDeprecations.splitDots(oldVersion.toString())
+            if (split.length < 2)
+                return
+            def removeVersion = MinecraftVersion.from("${split[0]}.${split[1] + 1}")
+            if (removeVersion <= mcVer)
+                errors.add([context(), removeVersion])
+        }
+    }
+
+    private static int[] splitDots(String version) {
+        String[] pts = version.split('\\.')
+        int[] values = new int[pts.length]
+        for (int x = 0; x < pts.length; x++)
+            values[x] = Integer.parseInt(pts[x])
+        return values
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckATs.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckATs.groovy
@ -0,0 +1,310 @@
+package net.minecraftforge.forge.tasks.checks
+
+import groovy.transform.CompileStatic
+import groovy.transform.TupleConstructor
+import net.minecraftforge.forge.tasks.InheritanceData
+import net.minecraftforge.srgutils.IMappingFile
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFile
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.InputFiles
+import org.gradle.api.tasks.Optional
+import org.objectweb.asm.Opcodes
+
+@CompileStatic
+abstract class CheckATs extends CheckTask {
+
+    @InputFile abstract RegularFileProperty getInheritance()
+    @InputFiles abstract ConfigurableFileCollection getAts()
+    @InputFile @Optional abstract RegularFileProperty getMappings()
+
+    @Override
+    void check(Reporter reporter, boolean fix) {
+        final IMappingFile mappings = mappings.map { RegularFile it -> IMappingFile.load(it.asFile) }.getOrNull()
+        final inheritance = InheritanceData.parse(this.inheritance.get().asFile)
+
+        ats.each {
+            final lines = process(it, reporter, inheritance)
+            if (fix) {
+                it.text = joinBack(lines, inheritance, mappings).join('\n')
+            }
+        }
+    }
+
+    private static TreeMap<String, ATParser.Entry> process(File file, Reporter reporter, Map<String, InheritanceData> inheritance) {
+        final TreeMap<String, ATParser.Entry> lines = ATParser.parse(file.readLines(), reporter)
+        final Map<String, ATParser.Entry> constructorGroups = [:]
+
+        final itr = lines.entrySet().iterator()
+        final toRemove = []
+        while (itr.hasNext()) {
+            final next = itr.next()
+            String key = next.key
+            final entry = next.value
+            if (entry === null) continue
+
+            final binaryName = entry.cls.replaceAll('\\.', '/')
+
+            // Process Groups, this will remove any entries outside the group that is covered by the group
+            if (entry.group) {
+                final jcls = inheritance[binaryName]
+                if (jcls === null) {
+                    itr.remove()
+                    reporter.report("Invalid group: $key")
+                } else if ('*' == entry.desc) {
+                    if (!jcls.fields) {
+                        itr.remove()
+                        reporter.report("Invalid group, class has no fields: $key")
+                    } else {
+                        jcls.fields.each { field, value ->
+                            final fkey = entry.cls + ' ' + field
+                            if (accessLevel(value.access) < accessStr(entry.modifier)) {
+                                if (lines.containsKey(fkey)) {
+                                    toRemove.add(fkey)
+                                } else if (!entry.existing.contains(fkey)) {
+                                    reporter.report("Missing group entry: $fkey")
+                                }
+                                entry.children.add(fkey)
+                            } else if (lines.containsKey(fkey)) {
+                                toRemove.add(fkey)
+                                reporter.report("Found invalid group entry: $fkey")
+                            }
+                        }
+                        entry.existing.findAll { it !in entry.children }.each { println('Removed: ' + it) }
+                    }
+                } else if ('*()' == entry.desc) {
+                    if (!jcls.methods) {
+                        itr.remove()
+                        reporter.report("Invalid group, class has no methods: $key")
+                    } else {
+                        jcls.methods.each { mtd, value ->
+                            if (mtd.startsWith('<clinit>') || mtd.startsWith('lambda$')) return
+                            key = entry.cls + ' ' + mtd.replace(' ', '')
+                            if (accessLevel(value.access) < accessStr(entry.modifier)) {
+                                if (lines.containsKey(key)) {
+                                    toRemove.add(key)
+                                } else if (!entry.existing.contains(key)) {
+                                    reporter.report("Missing group entry: $key")
+                                }
+                                entry.children.add(key)
+                            } else if (lines.containsKey(key)) {
+                                toRemove.add(key)
+                                reporter.report("Found invalid group entry: $key")
+                            }
+                        }
+                        entry.existing.findAll { it !in entry.children }.each { println('Removed: ' + it) }
+                    }
+                } else if ('<init>' == entry.desc) { //Make all public non-abstract subclasses
+                    constructorGroups.put(binaryName, entry)
+                }
+            }
+
+            // Process normal lines, remove invalid and remove narrowing
+            else {
+                def jcls = inheritance.get(binaryName)
+                if (jcls === null) {
+                    itr.remove()
+                    reporter.report("Invalid: $key")
+                } else if (entry.desc == '') {
+                    if (accessLevel(jcls.access) > accessStr(entry.modifier) && (entry.comment === null || !entry.comment.startsWith('#force '))) {
+                        itr.remove()
+                        reporter.report("Invalid Narrowing: $key")
+                    }
+                } else if (!entry.desc.contains('(')) {
+                    if (!jcls.fields || !jcls.fields.containsKey(entry.desc)) {
+                        itr.remove()
+                        reporter.report("Invalid: $key")
+                    } else {
+                        final value = jcls.fields[entry.desc]
+                        if (accessLevel(value.access) > accessStr(entry.modifier) && (entry.comment === null || !entry.comment.startsWith('#force '))) {
+                            itr.remove()
+                            reporter.report("Invalid Narrowing: $key - ${entry.comment}")
+                        }
+                    }
+                } else {
+                    final jdesc = entry.desc.replace('(', ' (')
+                    if (!jcls.methods || !jcls.methods.containsKey(jdesc)) {
+                        itr.remove()
+                        reporter.report("Invalid: $key")
+                    } else {
+                        final value = jcls.methods[jdesc]
+                        if (accessLevel(value.access) > accessStr(entry.modifier) && (entry.comment === null || !entry.comment.startsWith('#force '))) {
+                            itr.remove()
+                            reporter.report("Invalid Narrowing: $key")
+                        }
+                    }
+                }
+            }
+        }
+
+        inheritance.each { tcls, value ->
+            if (!value.methods || ((value.access & Opcodes.ACC_ABSTRACT) !== 0)) return
+            String parent = tcls
+            while (parent !== null) {
+                constructorGroups[parent]?.tap { entry ->
+                    value.methods.each { mtd, v ->
+                        if (mtd.startsWith('<init>')) {
+                            final child = tcls.replaceAll('/', '\\.') + ' ' + mtd.replace(' ', '')
+                            if (accessLevel(v.access) < 3) {
+                                if (lines.containsKey(child)) {
+                                    toRemove.add(child)
+                                } else if (child !in entry.existing) {
+                                    reporter.report("Missing group entry: $child")
+                                }
+                                entry.children.add(child)
+                            } else if (lines.containsKey(child)) {
+                                toRemove.add(child)
+                                reporter.report("Found invalid group entry: $child")
+                            }
+                        }
+                    }
+                }
+                parent = inheritance[parent]?.superName
+            }
+        }
+        constructorGroups.values().each { entry -> entry.existing.findAll { it !in entry.children }.each{  reporter.report("Found invalid group entry: $it") } }
+
+        toRemove.each(lines.&remove)
+
+        return lines
+    }
+
+    private static List<String> joinBack(TreeMap<String, ATParser.Entry> lines, Map<String, InheritanceData> inheritance, IMappingFile mappings) {
+        final data = [] as List<String>
+        final remapComment = { ATParser.Entry entry ->
+            if (!mappings || !entry || !entry.desc) return null
+            final comment = entry.comment?.substring(1)?.trim()
+            final jsonCls = inheritance.get(entry.cls.replaceAll('\\.', '/'))
+            final mappingsClass = mappings?.getClass(jsonCls.name)
+            if (mappingsClass === null) return entry.comment
+            final idx = entry.desc.indexOf('(')
+
+            String mappedName = idx == -1
+                    ? mappingsClass.remapField(entry.desc)
+                    : mappingsClass.remapMethod(entry.desc.substring(0, idx), entry.desc.substring(idx))
+            if (!mappedName) return entry.comment
+            if (mappedName == '<init>')
+                mappedName = 'constructor'
+
+            if (comment?.startsWith(mappedName))
+                return '# ' + comment
+            if (comment && comment.indexOf(' ') !== -1) {
+                def split = comment.split(' - ').toList()
+                if (split[0].indexOf(' ') !== -1)
+                // The first string is more than one word, so append before it
+                    return "# ${mappedName} - ${comment}"
+                split.remove(0)
+                return "# ${mappedName} - ${String.join(' - ', split)}"
+            }
+            return '# ' + mappedName
+        }
+        lines.each { key, value ->
+            if (!value.group) {
+                def comment = remapComment.call(value)
+                data.add(value.modifier + ' ' + key + (comment ? ' ' + comment : ''))
+            } else {
+                data.add(('#group ' + value.modifier + ' ' + key + ' ' + (value.comment ?: '')).trim())
+                value.children.each {
+                    final line = value.modifier + ' ' + it
+                    final entry = ATParser.parseEntry(line)
+                    final comment = remapComment(entry)
+                    data.add(line + (comment ? ' ' + comment : ''))
+                }
+                data.add('#endgroup')
+            }
+        }
+        return data
+    }
+
+    static int accessStr(String access) {
+        if (access.endsWith('-f') || access.endsWith('+f')) return 4
+        switch (access.toLowerCase()) {
+            case 'public':    return 3
+            case 'protected': return 2
+            case 'default':   return 1
+            case 'private':   return 0
+            default:          return -1
+        }
+    }
+
+    static int accessLevel(int access) {
+        if ((access & Opcodes.ACC_PUBLIC)    !== 0) return 3
+        if ((access & Opcodes.ACC_PROTECTED) !== 0) return 2
+        if ((access & Opcodes.ACC_PRIVATE)   !== 0) return 0
+        return 1
+    }
+}
+
+@CompileStatic
+class ATParser {
+    static TreeMap<String, Entry> parse(List<String> lines, CheckTask.Reporter reporter) {
+        TreeMap<String, Entry> outLines = new TreeMap<>()
+        Entry group = null
+        for (final line : lines) {
+            if (line.isEmpty()) continue
+            if (line.startsWith('#group ')) {
+                final entry = parseEntry(line.substring(7))
+
+                if (entry.desc != '*' && entry.desc != '*()' && entry.desc != '<init>') {
+                    reporter.report("Invalid group: $line", false)
+                }
+
+                entry.group = true
+                entry.children = []
+                entry.existing = []
+
+                group = entry
+
+                if (outLines.containsKey(entry.key)) {
+                    reporter.report("Duplicate group: $line", false)
+                }
+
+                outLines[entry.key] = group
+            } else if (group !== null) {
+                if (line.startsWith('#endgroup')) {
+                    group = null
+                } else {
+                    final key = parseEntry(line).key
+                    group.existing.add(key)
+                }
+            } else if (line.startsWith('#endgroup')) {
+                reporter.report("Invalid group ending: $line", false)
+            } else if (line.startsWith('#')) {
+                //Nom
+            } else {
+                final entry = parseEntry(line)
+                if (outLines.containsKey(entry.key)) {
+                    reporter.report("Found duplicate: $line")
+                    continue
+                }
+                outLines[entry.key] = entry
+            }
+        }
+        return outLines
+    }
+
+    static Entry parseEntry(String line) {
+        final idx = line.indexOf('#')
+        final String comment = idx === -1 ? null : line.substring(idx)
+        if (idx !== -1) line = line.substring(0, idx - 1)
+        final data = (line.trim() + '     ').split(' ', -1)
+        new Entry(data[0], data[1], data[2], comment)
+    }
+
+    @TupleConstructor
+    static final class Entry {
+        String modifier, cls, desc, comment
+
+        Set<String> existing
+        TreeSet<String> children
+        boolean group = false
+
+        @Lazy
+        String key = {cls + (desc.isEmpty() ? '' : ' ' + desc)}()
+
+        Object getAt(String key) {
+            return getProperty(key)
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckExcs.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckExcs.groovy
@ -0,0 +1,93 @@
+package net.minecraftforge.forge.tasks.checks
+
+import net.minecraftforge.forge.tasks.Util
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.InputFiles
+import org.objectweb.asm.ClassReader
+import org.objectweb.asm.ClassVisitor
+import org.objectweb.asm.MethodVisitor
+import org.objectweb.asm.Type
+
+import java.util.zip.ZipEntry
+import java.util.zip.ZipInputStream
+
+abstract class CheckExcs extends CheckTask {
+
+    @InputFile abstract RegularFileProperty getBinary()
+    @InputFiles abstract ConfigurableFileCollection getExcs()
+
+    @Override
+    void check(Reporter reporter, boolean fix) {
+        final Set<String> known = []
+        collectKnown(known)
+
+        excs.each { f ->
+            final lines = []
+            f.eachLine { line ->
+                def idx = line.indexOf('#')
+                if (idx == 0 || line.isEmpty()) {
+                    return
+                }
+
+                if (idx != -1) line = line.substring(0, idx - 1)
+
+                if (!line.contains('=')) {
+                    reporter.report("Invalid: $line")
+                    return
+                }
+
+                def (String key, String value) = line.split('=', 2)
+                if (!known.contains(key)) {
+                    reporter.report("Unknown: $line")
+                    return
+                }
+
+                String desc = key.split('\\.', 2)[1]
+                if (!desc.contains('(')) {
+                    reporter.report("Invalid: $line")
+                    return
+                }
+                desc = '(' + desc.split('\\(', 2)[1]
+
+                def (exceptions, String args) = value.contains('|') ? value.split('|', 2) : [value, '']
+
+                if (args.split(',').length !== Type.getArgumentTypes(desc).length) {
+                    reporter.report("Invalid: $line")
+                    return
+                }
+                lines.add(line)
+            }
+
+            if (fix) f.text = lines.sort().join('\n')
+        }
+    }
+
+    private void collectKnown(Collection<String> known) {
+        binary.get().asFile.withInputStream { i ->
+            new ZipInputStream(i).withCloseable { zin ->
+                final visitor = new ClassVisitor(Util.ASM_LEVEL) {
+                    private String cls
+                    @Override
+                    void visit(int version, int access, String name, String signature, String superName, String[] interfaces) {
+                        this.cls = name
+                    }
+
+                    @Override
+                    MethodVisitor visitMethod(int access, String name, String descriptor, String signature, String[] exceptions) {
+                        known.add(this.cls + '.' + name + descriptor)
+                        super.visitMethod(access, name, descriptor, signature, exceptions)
+                    }
+                }
+                ZipEntry zein
+                while ((zein = zin.nextEntry) !== null) {
+                    if (zein.name.endsWith('.class')) {
+                        ClassReader reader = new ClassReader(zin)
+                        reader.accept(visitor, ClassReader.SKIP_CODE | ClassReader.SKIP_DEBUG | ClassReader.SKIP_FRAMES)
+                    }
+                }
+            }
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckMode.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckMode.groovy
@ -0,0 +1,9 @@
+package net.minecraftforge.forge.tasks.checks
+
+import groovy.transform.CompileStatic
+
+@CompileStatic
+enum CheckMode {
+    CHECK,
+    FIX
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckPatches.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckPatches.groovy
@ -0,0 +1,182 @@
+package net.minecraftforge.forge.tasks.checks
+
+import groovy.transform.CompileStatic
+import org.gradle.api.file.DirectoryProperty
+import org.gradle.api.provider.ListProperty
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.InputDirectory
+import org.gradle.api.tasks.Optional
+
+import java.nio.file.Files
+import java.nio.file.Path
+import java.util.regex.Pattern
+
+@CompileStatic
+abstract class CheckPatches extends CheckTask {
+
+    private static final Pattern HUNK_START_PATTERN = Pattern.compile('^@@ -[0-9,]* \\+[0-9,_]* @@$')
+    private static final Pattern WHITESPACE_PATTERN = Pattern.compile('^[+\\-]\\s*$')
+    private static final Pattern IMPORT_PATTERN = Pattern.compile('^[+\\-]\\s*import.*')
+    private static final Pattern FIELD_PATTERN = Pattern.compile('^[+\\-][\\s]*((public|protected|private)[\\s]*)?(static[\\s]*)?(final)?([^=;]*)(=.*)?;\\s*$')
+    private static final Pattern METHOD_PATTERN = Pattern.compile('^[+\\-][\\s]*((public|protected|private)[\\s]*)?(static[\\s]*)?(final)?([^(]*)[(]([^)]*)?[)]\\s*[{]\\s*$')
+    private static final Pattern CLASS_PATTERN = Pattern.compile('^[+\\-][\\s]*((public|protected|private)[\\s]*)?(static[\\s]*)?(final[\\s]*)?(class|interface)([^{]*)[{]\\s*$')
+    private static final Map<String, Integer> ACCESS_MAP = [private: 0, protected: 2, public: 3].tap { it.put(null, 1) }
+
+    @InputDirectory abstract DirectoryProperty getPatchDir()
+    @Input @Optional abstract ListProperty<String> getPatchesWithS2SArtifact()
+
+    @Override
+    void check(Reporter reporter, boolean fix) {
+        final patchDir = getPatchDir().get().asFile.toPath()
+        Files.walk(patchDir).withCloseable {
+            it.filter(Files.&isRegularFile).forEach { path ->
+                final String relativeName = patchDir.relativize(path).toString()
+                verifyPatch(path, reporter, fix, relativeName, patchesWithS2SArtifact.get().contains(relativeName.replace('\\', '/')))
+            }
+        }
+    }
+    
+    def accessChange(previous, current) {
+        //return ACCESS_MAP[previous] < ACCESS_MAP[current]
+        return previous != current
+    }
+
+    void verifyPatch(Path patch, Reporter reporter, boolean fix, String patchPath, boolean hasS2SArtifact) {
+        final oldFixedErrors = reporter.fixed.size()
+
+        final lines = Files.readAllLines(patch)
+
+        int hunksStart = 0
+        boolean onlyWhiteSpace = false
+
+        final List<String> newLines = []
+
+        // First two lines are file name ++/-- and we do not care
+        newLines.add(lines[0] + '\n')
+        newLines.add(lines[1] + '\n')
+
+        int i
+        for (i = 2; i < lines.size(); ++i) {
+            def line = lines[i]
+            newLines.add(line + '\n')
+
+            if (HUNK_START_PATTERN.matcher(line).find()) {
+                if (onlyWhiteSpace) {
+                    if (!hasS2SArtifact)
+                        reporter.report("Patch contains only white space hunk starting at line ${hunksStart + 1}, file: $patchPath")
+                    int toRemove = i - hunksStart
+                    while (toRemove-- > 0)
+                        newLines.remove(newLines.size() - 1)
+                }
+                hunksStart = i
+                onlyWhiteSpace = true
+                continue
+            }
+
+            if (line.startsWithAny('+','-')) {
+                def prefixChange = false
+                def prevLine = lines[i - 1]
+
+                if (line.charAt(0) == (char)'+' && prevLine.charAt(0) == (char)'-') {
+                    def prevTrim = prevLine.substring(1).replaceAll("\\s", "")
+                    def currTrim = line.substring(1).replaceAll("\\s", "")
+
+                    if (prevTrim == currTrim) {
+                        prefixChange = true
+                    }
+
+                    def pMatcher = FIELD_PATTERN.matcher(prevLine)
+                    def cMatcher = FIELD_PATTERN.matcher(line)
+
+                    if (pMatcher.find() && cMatcher.find() &&
+                            pMatcher.group(6) == cMatcher.group(6) && // = ...
+                            pMatcher.group(5) == cMatcher.group(5) && // field name
+                            pMatcher.group(3) == cMatcher.group(3) && // static
+                            (accessChange(pMatcher.group(2), cMatcher.group(2)) || pMatcher.group(4) != cMatcher.group(4))) {
+                        reporter.report("Patch contains access changes or final removal at line ${i + 1}, file: $patchPath", false)
+                    }
+
+                    pMatcher = METHOD_PATTERN.matcher(prevLine)
+                    cMatcher = METHOD_PATTERN.matcher(line)
+
+                    if (pMatcher.find() && cMatcher.find() &&
+                            pMatcher.group(6) == cMatcher.group(6) && // params
+                            pMatcher.group(5) == cMatcher.group(5) && // <T> void name
+                            pMatcher.group(3) == cMatcher.group(3) && // static
+                            (accessChange(pMatcher.group(2), cMatcher.group(2)) || pMatcher.group(4) != cMatcher.group(4))) {
+                        reporter.report("Patch contains access changes or final removal at line ${i + 1}, file: $patchPath", false)
+                    }
+
+                    pMatcher = CLASS_PATTERN.matcher(prevLine)
+                    cMatcher = CLASS_PATTERN.matcher(line)
+
+                    if (pMatcher.find() && cMatcher.find() &&
+                            pMatcher.group(6) == cMatcher.group(6) && // ClassName<> extends ...
+                            pMatcher.group(5) == cMatcher.group(5) && // class | interface
+                            pMatcher.group(3) == cMatcher.group(3) && // static
+                            (accessChange(pMatcher.group(2), cMatcher.group(2)) || pMatcher.group(4) != cMatcher.group(4))) {
+                        reporter.report("Patch contains access changes or final removal at line ${i + 1}, file: $patchPath", false)
+                    }
+                }
+
+                if (line.charAt(0) == (char)'-' && i + 1 < lines.size()) {
+                    final nextLine = lines[i + 1]
+                    if (nextLine.charAt(0) == (char)'+') {
+                        final nextTrim = nextLine.substring(1).replaceAll("\\s", "")
+                        final currTrim = line.substring(1).replaceAll("\\s", "")
+
+                        if (nextTrim == currTrim) {
+                            prefixChange = true
+                        }
+                    }
+                }
+
+                final isWhiteSpaceChange = WHITESPACE_PATTERN.matcher(line).find()
+
+                if (!prefixChange && !isWhiteSpaceChange) {
+                    onlyWhiteSpace = hasS2SArtifact && IMPORT_PATTERN.matcher(line).find()
+                } else if (isWhiteSpaceChange) {
+                    final prevLineChange = prevLine.startsWithAny('+','-')
+                    final nextLineChange = i + 1 < lines.size() && lines[i + 1].startsWithAny('+','-')
+
+                    if (!prevLineChange && !nextLineChange) {
+                        reporter.report("Patch contains white space change in valid hunk at line ${i + 1}, file: $patchPath", false)
+                    }
+                }
+
+                if (line.contains('\t')) {
+                    reporter.report("Patch contains tabs on line ${i + 1}, file: $patchPath")
+                    line = line.replaceAll('\t', '    ')
+                    newLines.remove(newLines.size() - 1)
+                    newLines.add(line + '\n')
+                }
+
+                if (IMPORT_PATTERN.matcher(line).find() && !hasS2SArtifact) {
+                    reporter.report("Patch contains import change on line ${i + 1}, file: $patchPath", false)
+                }
+            }
+        }
+
+        if (onlyWhiteSpace) {
+            if (!hasS2SArtifact)
+                reporter.report("Patch contains only white space hunk starting at line ${hunksStart + 1}, file: $patchPath")
+            def toRemove = i - hunksStart;
+            while (toRemove-- > 0)
+                newLines.remove(newLines.size() - 1)
+        }
+
+        if ((reporter.fixed.size() > oldFixedErrors && fix) || hasS2SArtifact) {
+            if (newLines.size() <= 2) {
+                logger.lifecycle("Patch is now empty removing, file: {}", patchPath)
+                Files.delete(patch)
+            }
+            else {
+                if (!hasS2SArtifact)
+                    logger.lifecycle("*** Updating patch file. Please run setup then genPatches again. ***")
+                Files.newBufferedWriter(patch).withCloseable {
+                    newLines.each { l -> it.write(l) }
+                }
+            }
+        }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckSAS.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckSAS.groovy
@ -0,0 +1,110 @@
+package net.minecraftforge.forge.tasks.checks
+
+import groovy.transform.CompileStatic
+import net.minecraftforge.forge.tasks.Annotatable
+import net.minecraftforge.forge.tasks.InheritanceData
+import org.gradle.api.file.ConfigurableFileCollection
+import org.gradle.api.file.RegularFileProperty
+import org.gradle.api.tasks.InputFile
+import org.gradle.api.tasks.InputFiles
+
+@CompileStatic
+abstract class CheckSAS extends CheckTask {
+
+    @InputFile abstract RegularFileProperty getInheritance()
+    @InputFiles abstract ConfigurableFileCollection getSass()
+
+    @Override
+    void check(Reporter reporter, boolean fix) {
+        final inheritance = InheritanceData.parse(this.inheritance.get().asFile)
+
+        sass.each { f ->
+            final lines = []
+            f.eachLine { line ->
+                if (line[0] == '\t') return // Skip any tabbed lines, those are ones we add
+                final idx = line.indexOf('#')
+                if (idx == 0 || line.isEmpty()) {
+                    lines.add(line)
+                    return
+                }
+                def comment = idx == -1 ? null : line.substring(idx)
+                if (idx != -1) line = line.substring(0, idx - 1)
+                final spl = (line.trim().replace('(', ' (') + '     ').split(' ', -1)
+                def (String cls, String name, String desc) = [spl[0], spl[1], spl[2]]
+                cls = cls.replaceAll('\\.', '/')
+
+                if (inheritance[cls] === null) {
+                    reporter.report("Invalid: $line")
+                } else if (name.isEmpty()) { //Class SAS
+                    final toAdd = []
+                    final clsSided = isSided(inheritance[cls])
+                    boolean sided = clsSided
+
+                    /* TODO: MergeTool doesn't do fields
+                    if (json[cls]['fields'] != null) {
+                        for (entry in json[cls]['fields']) {
+                            if (isSided(entry.value)) {
+                                sided = true
+                                toAdd.add('\t' + cls + ' ' + entry.key)
+                            }
+						}
+                    } */
+
+                    final clsInh = inheritance[cls]
+                    if (clsInh.methods) {
+                        for (entry in clsInh.methods) {
+                            if (isSided(entry.value)) {
+                                sided = true
+                                toAdd.add('\t' + cls + ' ' + entry.key.replaceAll(' ', ''))
+                                findChildMethods(inheritance, cls, entry.key).each { lines.add('\t' + it) }
+                                findChildMethods(inheritance, cls, entry.key).each { println(line + ' -- ' + it) }
+                            } else if (clsSided) {
+                                findChildMethods(inheritance, cls, entry.key).each { lines.add('\t' + it) }
+                                findChildMethods(inheritance, cls, entry.key).each { println(line + ' -- ' + it) }
+                            }
+                        }
+                    }
+
+                    if (sided) {
+                        lines.add(cls + (comment == null ? '' : ' ' + comment))
+                        lines.addAll(toAdd.sort())
+                    } else {
+                        reporter.report("Invalid: $line")
+                    }
+
+                } else if (desc.isEmpty()) { // Fields
+                    /* TODO: MergeTool doesn't do fields
+                    if (json[cls]['fields'] != null && isSided(json[cls]['fields'][name]))
+                        lines.add(cls + ' ' + name + (comment == null ? '' : ' ' + comment))
+                    else */
+                    reporter.report("Invalid: $line")
+                } else { // Methods
+                    final clsInh = inheritance[cls]
+                    if (clsInh.methods === null || !isSided(clsInh.methods[name + ' ' + desc]))
+                        reporter.report("Invalid: $line")
+                    else {
+                        lines.add(cls + ' ' + name + desc + (comment == null ? '' : ' ' + comment))
+                        findChildMethods(inheritance, cls, name + ' ' + desc).each { println(line + ' -- ' + it) }
+                        findChildMethods(inheritance, cls, name + ' ' + desc).each { lines.add('\t' + it) }
+                    }
+                }
+            }
+
+            if (fix) f.text = lines.join('\n')
+        }
+    }
+
+    protected static isSided(Annotatable annotatable) {
+        if (annotatable === null) return false
+        for (ann in annotatable.annotations) {
+            if ('Lnet/minecraftforge/api/distmarker/OnlyIn;' == ann.desc)
+                return true
+        }
+        return false
+    }
+    
+    protected static findChildMethods(Map<String, InheritanceData> json, String cls, String desc) {
+        return json.values().findAll{ it.methods != null && it.methods[desc] != null && it.methods[desc].override == cls && isSided(it.methods[desc]) }
+                .collect { it.name + ' ' + desc.replace(' ', '') } as TreeSet
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckTask.groovy
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/CheckTask.groovy
@ -0,0 +1,111 @@
+package net.minecraftforge.forge.tasks.checks
+
+import groovy.transform.CompileStatic
+import net.minecraftforge.forge.tasks.Util
+import org.gradle.api.Action
+import org.gradle.api.DefaultTask
+import org.gradle.api.logging.LogLevel
+import org.gradle.api.provider.Property
+import org.gradle.api.tasks.Input
+import org.gradle.api.tasks.TaskAction
+import org.gradle.api.tasks.TaskContainer
+import org.gradle.api.tasks.VerificationTask
+
+@CompileStatic
+abstract class CheckTask extends DefaultTask implements VerificationTask {
+    @Input
+    abstract Property<CheckMode> getMode()
+
+    private boolean ignoreFailures = false
+
+    @Input
+    @Override
+    boolean getIgnoreFailures() {
+        return ignoreFailures
+    }
+
+    @Override
+    void setIgnoreFailures(boolean ignoreFailures) {
+        this.ignoreFailures = ignoreFailures
+    }
+
+    @TaskAction
+    void run() {
+        Util.init()
+
+        final doFix = getMode().get() === CheckMode.FIX
+        final Reporter reporter = new Reporter(doFix)
+        check(reporter, doFix)
+
+        if (reporter.messages) {
+            if (getMode().get() === CheckMode.CHECK) {
+                logger.error("Check task '{}' found errors:\n{}", name, reporter.messages.join('\n'))
+                if (!ignoreFailures) {
+                    throw new IllegalArgumentException("${reporter.messages.size()} errors were found!")
+                }
+            } else {
+                if (logger.isEnabled(LogLevel.DEBUG)) {
+                    logger.warn("Check task '{}' found {} errors and fixed {}:\n{}", name, reporter.messages.size(), reporter.fixed.size(), reporter.fixed.join('\n'))
+                } else {
+                    logger.warn("Check task '{}' found {} errors and fixed {}.", name, reporter.messages.size(), reporter.fixed.size())
+                }
+
+                if (reporter.notFixed) {
+                    logger.error('{} errors could not be fixed:\n{}', reporter.notFixed.size(), reporter.notFixed.join('\n'))
+                    if (!ignoreFailures) {
+                        throw new IllegalArgumentException("${reporter.notFixed.size()} errors which cannot be fixed were found!")
+                    }
+                }
+            }
+        }
+    }
+
+    abstract void check(Reporter reporter, boolean fix)
+
+    @CompileStatic
+    static final class Reporter {
+        final boolean trackFixed
+        Reporter(boolean trackFixed) {
+            this.trackFixed = trackFixed
+        }
+
+        public final List<String> messages = []
+
+        public final List<String> fixed = []
+        public final List<String> notFixed = []
+
+        void report(String message, boolean canBeFixed = true) {
+            messages.add(message)
+
+            if (trackFixed) {
+                if (canBeFixed) {
+                    fixed.add(message)
+                } else {
+                    notFixed.add(message)
+                }
+            }
+        }
+    }
+
+    static <T extends CheckTask> void registerTask(TaskContainer tasks, String taskName, @DelegatesTo.Target('type') Class<T> clazz,
+                                                   @DelegatesTo(genericTypeIndex = 0, target = 'type') Closure configuration) {
+        taskName = taskName.capitalize()
+        tasks.register("check$taskName", clazz) { CheckTask task ->
+            def castedTask = task as T
+            configuration.setDelegate(castedTask)
+            configuration.call(castedTask)
+            castedTask.mode.set(CheckMode.CHECK)
+            castedTask.group = 'checks'
+        }
+        tasks.named('checkAll').configure { it.dependsOn("check$taskName") }
+
+        tasks.register("checkAndFix$taskName", clazz) { CheckTask task ->
+            def castedTask = task as T
+            configuration.setDelegate(castedTask)
+            configuration.call(castedTask)
+            castedTask.mode.set(CheckMode.FIX)
+            castedTask.group = 'checks'
+        }
+        tasks.named('checkAllAndFix').configure { it.dependsOn("checkAndFix$taskName") }
+    }
+}
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/index.html
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/index.html
@ -0,0 +1,13 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/checks/</h1><hr><pre><a href="../">../</a>
+<a href="CheckATs.groovy">CheckATs.groovy</a>                                    07-Oct-2023 14:12     13K
+<a href="CheckExcs.groovy">CheckExcs.groovy</a>                                   07-Oct-2023 14:12    3336
+<a href="CheckMode.groovy">CheckMode.groovy</a>                                   07-Oct-2023 14:12     139
+<a href="CheckPatches.groovy">CheckPatches.groovy</a>                                07-Oct-2023 14:12    8618
+<a href="CheckSAS.groovy">CheckSAS.groovy</a>                                    07-Oct-2023 14:12    5039
+<a href="CheckTask.groovy">CheckTask.groovy</a>                                   07-Oct-2023 14:12    3994
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="df76f234be1cfa5f0a12b7f8d2017b09" data-cf-beacon='{"rayId":"85f03933fbe81c4c","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/index.html
+++ b/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/index.html
@ -0,0 +1,25 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/forge/tasks/</h1><hr><pre><a href="../">../</a>
+<a href="checks/">checks/</a>                                            07-Oct-2023 14:12       -
+<a href="BytecodeFinder.groovy">BytecodeFinder.groovy</a>                              07-Oct-2023 14:12    1598
+<a href="BytecodePredicateFinder.groovy">BytecodePredicateFinder.groovy</a>                     07-Oct-2023 14:12     976
+<a href="ClosureHelper.groovy">ClosureHelper.groovy</a>                               07-Oct-2023 14:12     886
+<a href="Crowdin.groovy">Crowdin.groovy</a>                                     07-Oct-2023 14:12    2244
+<a href="DownloadLibraries.groovy">DownloadLibraries.groovy</a>                           07-Oct-2023 14:12    1880
+<a href="FieldCompareFinder.groovy">FieldCompareFinder.groovy</a>                          07-Oct-2023 14:12    3265
+<a href="FixPatchImports.groovy">FixPatchImports.groovy</a>                             07-Oct-2023 14:12    1525
+<a href="InheritanceData.groovy">InheritanceData.groovy</a>                             07-Oct-2023 14:12    1251
+<a href="InstallerJar.groovy">InstallerJar.groovy</a>                                07-Oct-2023 14:12    1771
+<a href="InstallerJson.groovy">InstallerJson.groovy</a>                               07-Oct-2023 14:12    3360
+<a href="LauncherJson.groovy">LauncherJson.groovy</a>                                07-Oct-2023 14:12    3051
+<a href="MergeJars.groovy">MergeJars.groovy</a>                                   07-Oct-2023 14:12    1544
+<a href="ObjectTarget.groovy">ObjectTarget.groovy</a>                                07-Oct-2023 14:12     646
+<a href="SetupCheckJarCompatibility.groovy">SetupCheckJarCompatibility.groovy</a>                  07-Oct-2023 14:12    2166
+<a href="TeamcityRequests.groovy">TeamcityRequests.groovy</a>                            07-Oct-2023 14:12    2348
+<a href="Util.groovy">Util.groovy</a>                                        07-Oct-2023 14:12    5707
+<a href="ValidateDeprecations.groovy">ValidateDeprecations.groovy</a>                        07-Oct-2023 14:12    3371
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="3f8bbda218cac2789d8c0668dff0dbc4" data-cf-beacon='{"rayId":"85f02692e9141c5c","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/groovy/net/minecraftforge/index.html
+++ b/buildSrc/src/main/groovy/net/minecraftforge/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/groovy/net/minecraftforge/</h1><hr><pre><a href="../">../</a>
+<a href="forge/">forge/</a>                                             07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="64ea8c6229528843600474580cb177e7" data-cf-beacon='{"rayId":"85f016b34c7050c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>
--- a/buildSrc/src/main/index.html
+++ b/buildSrc/src/main/index.html
@ -0,0 +1,8 @@
+<html>
+<head><title>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/</title></head>
+<body>
+<h1>Index of /mirror/src/Magma-1-20-x/buildSrc/src/main/</h1><hr><pre><a href="../">../</a>
+<a href="groovy/">groovy/</a>                                            07-Oct-2023 14:12       -
+</pre><hr><script defer src="https://static.cloudflareinsights.com/beacon.min.js/v84a3a4012de94ce1a686ba8c167c359c1696973893317" integrity="sha512-euoFGowhlaLqXsPWQ48qSkBSCFs3DPRyiwVu3FjR96cMPx+Fr+gpWRhIafcHwqwCqWS42RZhIudOvEI+Ckf6MA==" nonce="b9153e4f45647d70eaf262525473375b" data-cf-beacon='{"rayId":"85f0155fea8c50c2","version":"2024.2.4","r":1,"token":"583109dda43e47a593fd006526a81120","b":1}' crossorigin="anonymous"></script>
+</body>
+</html>